*******************************
*Varistor PSpice Model Netlist*
*******************************
*
* © 	Littelfuse Inc.
*	6th April 2004
*	version 4.0
*
* Representing typical characteristics for the following MHS-Series varistors: 
*
* V0402MHS03	V0603MHS03
* V0402MHS12	V0603MHS12
* V0402MHS22	V0603MHS22
*
.SUBCKT MHSMOV  1 2 PARAMS: T=1 C=1pF L=1nH a1=1 a2=0 a3=0 a4=0 a5=0 a6=100u a7=100u
E_non_lin	3 1 	VALUE {T*(
+ 			a1+a2*(log10(limit(v(4),a7,1g))-3)
+			+a3*2^(-log10(limit(v(4),a7,1g))+3)
+			+a4*exp(-log10(limit(v(4),a7,1g))+3)
+ 			+a5*exp(log10(limit(v(4),a7,1g))-3)
+ 			-(a1+a2*(log10(-limit(v(4),-1g,-a7))-3)
+			+a3*2^(-log10(-limit(v(4),-1g,-a7))+3)
+			+a4*exp(-log10(-limit(v(4),-1g,-a7))+3)
+ 			+a5*exp(log10(-limit(v(4),-1g,-a7))-3))
+ 			+limit(v(4)/a7*v(8),-v(8),v(8)))}
L_series	5 6  {L}  
H_H1		4 0  VH_H1 1k
VH_H1		5 7 0V
R_R2		0 4  1G  
R_series	6 2  {a6}  
V_V1		3 7  0V
E_x_zero	8 0 	VALUE {a1+a2*(log10(a7/1e3))+a3*2^(-log10(a7/1e3))
+			+a4*exp(-log10(a7/1e3))+a5*exp(log10(a7/1e3))}
R_x_zero	8 0  1G
C_parallel	1 5 {C}
.ENDS
*
.SUBCKT V0402MHS03 1 2 PARAMS: TOL=0
X1	1 2	MHSMOV PARAMS: T={1+TOL/100} L=1nH C=3pF a1=75.78 a2=8.133 a3=1.408 a4=-0.1752 a5=21.34 a6=887E-3
.ENDS
*
.SUBCKT V0402MHS12 1 2 PARAMS: TOL=0
X1	1 2	MHSMOV PARAMS: T={1+TOL/100} L=1nH C=12pF a1=32.84 a2=2.451 a3=0.3199 a4=-0.04852 a5=8.592 a6=623E-6
.ENDS
*
.SUBCKT V0402MHS22 1 2 PARAMS: TOL=0
X1	1 2	MHSMOV PARAMS: T={1+TOL/100} L=1nH C=22pF a1=16.29 a2=1.908 a3=0.2937 a4=-0.03302 a5=4.955 a6=185.2E-3
.ENDS
*
.SUBCKT V0603MHS03 1 2 PARAMS: TOL=0
X1	1 2	MHSMOV PARAMS: T={1+TOL/100} L=1nH C=3pF a1=75.78 a2=8.133 a3=1.408 a4=-0.1752 a5=21.34 a6=887E-3
.ENDS
*
.SUBCKT V0603MHS12 1 2 PARAMS: TOL=0
X1	1 2	MHSMOV PARAMS: T={1+TOL/100} L=1nH C=12pF a1=32.84 a2=2.451 a3=0.3199 a4=-0.04852 a5=8.592 a6=623E-6
.ENDS
*
.SUBCKT V0603MHS22 1 2 PARAMS: TOL=0
X1	1 2	MHSMOV PARAMS: T={1+TOL/100} L=1nH C=22pF a1=16.29 a2=1.908 a3=0.2937 a4=-0.03302 a5=4.955 a6=185.2E-3
.ENDS
*