*******************************
*Varistor PSpice Model Netlist*
*******************************
*
* © 	Littelfuse Inc.
*
*     April 6, 2007
*	version 4.3
*
* Representing typical characteristics for the following TMOV34S-Series varistors: 
*
* TMOV34S111M TMOV34S131M TMOV34S151M TMOV34S181M
* TMOV34S201M TMOV34S251M TMOV34S271M TMOV34S301M
* TMOV34S321M TMOV34S331M TMOV34S351M TMOV34S391M
* TMOV34S421M TMOV34S461M TMOV34S481M TMOV34S511M
* TMOV34S551M TMOV34S571M TMOV34S621M TMOV34S661M
* TMOV34S681M TMOV34S751M
*
.SUBCKT TMOV34S  1 2 PARAMS: T=1 C=1pF L=1nH a1=1.00 a2=23.63E-3 a3=275.397E-6 
+     a4=-1.07E-3 a5=2.912E-3 a6=2.452E-3 a7=100u
E_non_lin	3 1	VALUE {T*(
+	10^(
+	+a1+a2*(log10(limit(v(4),a7,1g))-3)
+	+a3*2^(-log10(limit(v(4),a7,1g))+3)
+	+a4*exp(-log10(limit(v(4),a7,1g))+3)
+	+a5*exp(log10(limit(v(4),a7,1g))-3)
+	+a6*2^(log10(limit(v(4),a7,1g))-3)
+	)
+	-10^(
+	a1+a2*(log10(-limit(v(4),-1g,-a7))-3)
+	+a3*2^(-log10(-limit(v(4),-1g,-a7))+3)
+	+a4*exp(-log10(-limit(v(4),-1g,-a7))+3)
+	+a5*exp(log10(-limit(v(4),-1g,-a7))-3)
+	+a6*2^(log10(-limit(v(4),-1g,-a7))-3)
+	)
+	+limit(v(4)/a7*v(8),-v(8),v(8))
+	)}
L_series	5 6  {L}  
H_H1		4 0  VH_H1 1k
VH_H1		5 70 0V
R_R2		0 4  1  
R_series	6 2  100u  
V_V1		3 70  0V
E_x_zero	8 0 	VALUE {10^(
+	a1+a2*(log10(a7/1e3))
+	+a3*2^(-log10(a7/1e3))
+	+a4*exp(-log10(a7/1e3))
+	+a5*exp(log10(a7/1e3))
+	+a6*2^(log10(a7/1e3))
+	)}
R_x_zero	8 0  1
C_parallel	1 5 {C}
.ENDS
.SUBCKT TMOV34S111M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=11.5nF a1=2.345 
.ENDS
*
.SUBCKT TMOV34S131M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=10nF a1=2.391 
.ENDS
*
.SUBCKT TMOV34S141M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=9nF a1=2.432 
*
.SUBCKT TMOV34S151M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=8nF a1=2.47 
.ENDS
*
.SUBCKT TMOV34S181M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=6.8nF a1=2.537
.ENDS
*
.SUBCKT TMOV34S201M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=6.5nF a1=2.595 
.ENDS
*
.SUBCKT TMOV34S251M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=5nF a1=2.681 
.ENDS
*
.SUBCKT TMOV34S271M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=4.5nF a1=2.723 
.ENDS
*
.SUBCKT TMOV34S301M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=4.05nF a1=2.769 
.ENDS
*
.SUBCKT TMOV34S321M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=3.8nF a1=2.797
.ENDS
*
.SUBCKT TMOV34S331M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=3.7nF a1=2.814 
.ENDS
*
.SUBCKT TMOV34S351M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=3.5nF a1=2.838 
.ENDS
*
.SUBCKT TMOV34S391M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=3.3nF a1=2.882 
.ENDS
*
.SUBCKT TMOV34S421M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=3nF a1=2.922 
.ENDS
*
.SUBCKT TMOV34S461M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=2.8nF a1=2.941 
.ENDS
*
.SUBCKT TMOV34S481M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=2.7nF a1=2.965 
.ENDS
*
.SUBCKT TMOV34S511M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=2.5nF a1=3.003 
.ENDS
*
.SUBCKT TMOV34S551M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=2.25nF a1=3.022 
.ENDS
*
.SUBCKT TMOV34S571M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=2.2nF a1=3.049 
.ENDS
*
.SUBCKT TMOV34S621M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=2.1nF a1=3.081 
.ENDS
*
.SUBCKT TMOV34S661M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=2nF a1=3.111 
.ENDS
*
.SUBCKT TMOV34S681M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=1.97nF a1=3.127 
.ENDS
*
.SUBCKT TMOV34S751M 1 2 PARAMS: TOL=0
X1	1 2	TMOV34S PARAMS: T={1+TOL/100} L=20nH C=1.8nF a1=3.169 
.ENDS
*